# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/geneweb/geneweb-5.02.ebuild,v 1.6 2012/06/01 01:56:55 zmedico Exp $

EAPI=2
inherit eutils user

DESCRIPTION="Genealogy software program with a Web interface."
HOMEPAGE="http://cristal.inria.fr/~ddr/GeneWeb/"
SRC_URI="http://opensource.geneanet.org/attachments/download/190/gw-6.05-src.tgz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 x86"

RDEPEND="dev-lang/ocaml
	dev-ml/camlp5"
DEPEND="${RDEPEND}"
#	!net-p2p/ghostwhitecrab"

S=${WORKDIR}/gw-6.05-src

src_compile() {
	make || die "Compiling byte code executables failed"
}

src_install() {
	make distrib || die "Failed making distrib"
	cd distribution/gw
	# Install doc
	dodoc CHANGES.txt
	# Install binaries
	dobin gwc gwc2 consang gwd gwu update_nldb ged2gwb gwb2ged gwsetup \
		|| die "Failed installing binaries"
	insinto /usr/lib/${PN}
	doins -r gwtp_tmp/* || die "Failed installing CGI program"
	dodoc a.gwf
	dohtml -r doc/*
	insinto /usr/share/${PN}
	doins -r etc images lang setup gwd.arg only.txt\
		|| die "Failed installing data"

	cd ../..

	# Install binaries
	dobin src/check_base \
		|| die "Failed installing check_base binaries"
	# Install manpages
	doman man/* || die "Failed installing man pages"

	# Install doc
	dodoc ICHANGES
	insinto /usr/share/doc/${PF}/contrib
	doins -r contrib/{gwdiff,misc} \
		|| die "Failed installing contributions"

	newinitd "${FILESDIR}/geneweb.initd" geneweb
	newconfd "${FILESDIR}/geneweb.confd" geneweb
}

pkg_postinst() {
	enewuser geneweb "" "/bin/bash" /var/lib/geneweb
	einfo "A CGI program has been installed in /usr/lib/${PN}. Follow the"
	einfo "instructions on the README in that directory to use it"
}